/*

‍Voltaat learn (http://learn.voltaat.com)

Tutorial: Automated muezzin project using Arduino!

Connections from the Arduino to the breadboard:

• Arduino 5v pin → breadboard 5v line

• Arduino GND pin → breadboard GND line

Connections from the MP3 Module:

• VCC pin of the MP3 module → breadboard 5v line

• GND pin of the MP3 module → breadboard GND line

• TX pin of the MP3 module → Arduino pin 10

• RX pin of the MP3 module → The middle pin between the 1 kΩ resistor and the 680 Ω resistor

• First pin of the 1 kΩ resistor → Negative pins on the breadboard

• Other pin of the 680 Ω resistor → Arduino pin 11

• SPK_1 pin of the MP3 module → First terminal of the speaker

• SPK_2 pin of the MP3 module → Second terminal of the speaker

Connections from the RTC Module:

• VCC pin of the RTC module → breadboard 5v line

• GND pin pin of the RTC module → breadboard GND line

• SDA pin of the RTC module → Arduino pin A4

• SCL pin of the RTC module → Arduino pin A5

Connections from the LCD:

• I2C module GND pin → Breadboard GND line

• I2C module 5V pin → breadboard GND line

• I2C module SDA pin → Arduino pin A4

• I2C module SCL pin → Arduino pin A5

*/

#include <RTClib.h>

#include <LiquidCrystal_I2C.h>

#include "DFRobotDFPlayerMini.h"

#include <SoftwareSerial.h>

// Initialize RTC and I2C LCD

RTC_DS3231 rtc; // Using RTC_DS3231 from RTCLib

LiquidCrystal_I2C lcd(0x27, 16, 2); // Set the LCD I2C address (0x27 is common, check yours)

const char* Elfajr = "04:34AM";

const char* Eldhuhr = "11:21AM";

const char* Elasr = "02:25PM";

const char* Elmaghrib = "04:45PM";

const char* Elisha   = "06:15PM";

// Fixed alarm times and corresponding names

const char* alarmTimes[5] = {Elfajr, Eldhuhr, Elasr, Elmaghrib, Elisha};

const char* alarmNames[5] = {"Elfajr", "Eldhuhr", "Elasr", "Elmaghrib", "Elisha"};

// DFRobotDFPlayer Mini setup

SoftwareSerial mySerial(10, 11); // RX, TX

DFRobotDFPlayerMini myDFPlayer;

// To track if an alarm was already triggered for the current minute

bool alarmTriggered = false;

const char* currentAlarmName = nullptr;

void setup() {

  // Initialize RTC

  if (!rtc.begin()) {

    lcd.init();

    lcd.backlight();

    lcd.print("RTC Error");

    while (1); // Halt if RTC is not connected

  }

  // Initialize LCD

  lcd.init();

  lcd.backlight();

  lcd.print("Initializing...");

  delay(2000);

  lcd.clear();

  // Initialize DFRobotDFPlayer Mini

  mySerial.begin(9600); // Communication with DFPlayer Mini

  if (!myDFPlayer.begin(mySerial)) {

    lcd.print("DFPlayer Error");

    while (1); // Halt if DFPlayer Mini is not connected

  }

  myDFPlayer.volume(20); // Set volume (0 to 30)

  lcd.print("System Ready");

  delay(2000);

  lcd.clear();

}

void loop() {

  // Get the current time

  DateTime now = rtc.now();

  // Convert to 12-hour format

  int hour12 = now.hour() % 12;

  if (hour12 == 0) hour12 = 12; // Adjust for 12-hour clock

  const char* meridiem = now.hour() >= 12 ? "PM" : "AM";

  // Display time and date in 12-hour format on the first line

  lcd.setCursor(0, 0);

  if (now.day() < 10) lcd.print("0"); // Leading zero for day

  lcd.print(now.day(), DEC);

  lcd.print("/");

  if (now.month() < 10) lcd.print("0"); // Leading zero for month

  lcd.print(now.month(), DEC);

  lcd.print("/");

  lcd.print(now.year(), DEC);

  lcd.print(" ");

  if (hour12 < 10) lcd.print("0"); // Leading zero for hour

  lcd.print(hour12, DEC);

  lcd.print(":");

  if (now.minute() < 10) lcd.print("0"); // Leading zero for minute

  lcd.print(now.minute(), DEC);

  lcd.print(meridiem);

  // Check if it's time to trigger any alarm

  int alarmIndex = getAlarmIndex(hour12, now.minute(), meridiem);

  if (alarmIndex != -1 && !alarmTriggered) {

    currentAlarmName = alarmNames[alarmIndex];

    playSong();

    alarmTriggered = true; // Avoid retriggering in the same minute

  }

  // Display alarm name on the second line if active

  if (currentAlarmName != nullptr) {

  lcd.setCursor(4, 1);

    lcd.print(currentAlarmName);

  } else {

    lcd.setCursor(0, 1);

    lcd.print("                "); // Clear the second line

  }

  // Reset alarm trigger flag after the minute changes

  if (alarmIndex == -1) {

    alarmTriggered = false;

    currentAlarmName = nullptr;

  }

  delay(1000);

}

// Function to get the index of the current alarm

int getAlarmIndex(int currentHour12, int currentMinute, const char* currentMeridiem) {

  char currentTime[8];

  sprintf(currentTime, "%02d:%02d%s", currentHour12, currentMinute, currentMeridiem);

  for (int i = 0; i < 5; i++) {

    if (strcmp(currentTime, alarmTimes[i]) == 0) {

      return i;

    }

  }

  return -1;

}

// Function to play the song using DFRobotDFPlayer Mini

void playSong() {

  myDFPlayer.play(1); // Play song 001 (index 1 on the SD card)

  delay(100); // Play for 10 seconds

}

‍